Arachnida on acid - OpenProcessing

mySketch
xxxxxxxxxx
 
// Mouse click to cycle through the 5 variations.
// Inspired by Jared Tarbell's "substrate"
// ArrayList, boolean, class
​
​
ArrayList<Line> lines;
boolean straight = false, curve = false, rightAngleFork = true;
int choose = 0;
​
void setup() { 
  //fullscreen();
  size(500, 500);
  background(0);
  smooth();
  lines = new ArrayList<Line>();
​
  if (choose == 0) {
    fill(255);
    textAlign(CENTER);
    text("mouse click to start", width/2, height/2);
  } else if (choose != 0) {
    if (choose == 5) {
      lines.add(new Line(width/2, height/2, radians(random(120))));
      lines.add(new Line(width/2, height/2, radians(random(125, 240))));
      lines.add(new Line(width/2, height/2, radians(random(245, 350))));
    } else {
      lines.add(new Line(random(200, width-200), random(200, height-200), radians(random(360))));
      lines.add(new Line(random(200, width-200), random(200, height-200), radians(random(360))));
      lines.add(new Line(random(200, width-200), random(200, height-200), radians(random(360))));
      lines.add(new Line(random(200, width-200), random(200, height-200), radians(random(360))));
      lines.add(new Line(random(200, width-200), random(200, height-200), radians(random(360))));
    }
  }
}
​
void draw() {
  for (int i = 0; i < lines.size (); i++) {
    Line l = lines.get(i);
    if (l.isDead)lines.remove(i);
    else l.update();
  }
​
  fill(0);
  noStroke();
  rect(30, 30, 30, 30);
  fill(255);
  text(round(frameRate), 50, 50);
}
​
void mousePressed() {
  choose++;
  if (choose > 5) choose = 1;
​
  if (choose == 3) { // curved with 90 deg fork
    curve = rightAngleFork = true;
    straight  = false;
  }
​
  if (choose == 2 || choose == 4 || choose == 5) { // straight with 90 deg or random fork
    straight =  rightAngleFork = true;             // 5 draws from mid monitor
    curve  =  false;
    if (choose == 4 || choose == 5) rightAngleFork = false;
  }
​
  if (choose == 1) {
    straight = curve = false; // wiggle with 90 deg fork
    rightAngleFork = true;
  }
​
  background(0);
  setup();
}
​
​
//// Class %%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%%
​
class Line {
  boolean isDead;
  float x, y, dx, dy, oldX, oldY, dir, threshold, vel, val;
​
  Line(float xIn, float yIn, float dirIn) {
    isDead = false;
    oldX = x = xIn;
    oldY = y = yIn;
    dir = dirIn;
    threshold = random(0.1);
    vel = 2;
  }
​
​
  void update() {
    stroke(255);
    strokeWeight(.5);
    line(oldX, oldY, x, y);
​
    oldX = x;
    oldY = y;
​
    if (curve)  dir += .004; 
    else if (curve == false && straight == false ) {// wiggle
      val = random(1);
      if (val < .1) dir -= .09; // pi/35, about 5 degrees
      else if (val > .9) dir += .09;
    }  
​
    dx = vel * cos(dir);
    dy = vel * sin(dir);
​
    x += dx;
    y += dy;
​
    if (get(int(x), int(y)) !=  -16777216) isDead = true; 
    else if (random(.85) < threshold)
      if (rightAngleFork)lines.add(new Line(x, y, dir + ((round(random(1))*2-1) * PI/2))); 
      else lines.add(new Line(x, y, dir + random(-1, 1) * PI/2));// or random(TWO_PI)
  }
}
​
​
​