Hommage à Frieder Nake. - OpenProcessing

mySketch
xxxxxxxxxx
 
// Hommage à Frieder Nake.
// Irregular (slightly) quadrilaterals drawn on paper with a pencil. 
// random, noLoop, vertex, randomGaussian, redraw, PShape.
// polygon, rectangle, quadrilateral. 
// Mouse click for new quads.
​
​
float xPos, yPos, wdth, hght, irreg;
int paperW, paperH, paperX, paperY;
​
void setup() {
  size(1200, 650);
  //fullscreen()
  smooth();
  background(0);
  paperW = 300;
  paperH = 500;
  paperX = 450;
  paperY = 75;
}
​
void draw() {
​
  drawPaper(paperX, paperY, paperW, paperH);
​
  for (int i = 0; i < 8; i++) {
    irreg = random(8);
    wdth = random(30, 250);
    xPos = random(paperX +10, paperX + paperW - wdth - irreg);
    hght = random(50, 400);
    yPos = random(paperY + 10, paperY + paperH - hght - irreg);
    drawQuad(xPos, yPos, wdth, hght, irreg);
  }
  noLoop();
}
​
// Not very elegant, but it will do.
void drawQuad(float x, float y, float w, float h, float irregular) {
  noFill();
  beginShape();
  float  adjX = random(-irregular, irregular);
  float  adjY = random(-irregular, irregular);
  drawLine(x, y, x + w + adjX, y + adjY);
  float  adjX2 = random(-irregular, irregular);
  float  adjY2 = random(-irregular, irregular);
  drawLine(x+w + adjX, y + adjY, x + w + adjX2, y + h + adjY2);
  float  adjX3 = random(-irregular, irregular);
  float  adjY3 = random(-irregular, irregular);
  drawLine(x+w + adjX2, y+h+ adjY2, x+ adjX3, y+h+ adjY3);
  drawLine(x + adjX3, y+h+adjY3, x, y);
  endShape();
}
​
​
void drawLine(float strtx, float strty, float finx, float finy) { 
  int  numSegs = 50;
  float fraction = 0;
  int  divBy = numSegs;
  float x1 = strtx;
  float y1 = strty;
  stroke(0);
  strokeWeight(random(.1, 1.5));
  for (int j = 0; j <= int (numSegs); j++) {
    float x = (randomGaussian()*.3) +x1 + (fraction * (finx-x1));
    float y = (randomGaussian()*.3) +y1 + (fraction * (finy-y1));
    vertex(x, y);
    x1 = x;
    y1 = y;
    fraction = 1.0/divBy--;
  }
}
​
void drawPaper(int x, int y, int w, int h) {
  noStroke();
  fill(255);
  rect(x, y, w, h);
  for (int i = x; i< w + x-1; i+=2) {
    for (int j = y; j< h + y-1; j+=2) {
      fill(random (220, 255), 150);
      rect(i, j, 2, 2);
    }
  }
  for (int i = 0; i<30; i++) {
    fill(random(150, 200), 150);
    rect(random(x, x + w-2), random(y, y + h-2), random(1, 3), random(1, 3));
  }
}
​
void mousePressed() {
  background(0);
  redraw();
}
​