Cubic Bézier Curve Interpolation

PVector acr1, acr2, ctl1, ctl2;

PVector itp, itpCtl1, itpCtl2;

​

float ratio;

​

void setup() {

  size(720, 720);

  smooth();

  frameRate(30);

​

  initBezier();

}

​

void initBezier() {

  PVector dir = PVector.random2D();

  acr1 = PVector.mult(dir, 200);

  acr2 = PVector.mult(PVector.mult(dir, -1), 200);

  ctl1 = PVector.add(acr1, PVector.mult(PVector.random2D(), 100));

  ctl2 = PVector.add(acr2, PVector.mult(PVector.random2D(), 100));

​

  itp = new PVector(0, 0);

  itpCtl1 = new PVector(0, 0);

  itpCtl2 = new PVector(0, 0);

}

​

void updateItpBezier() {

  itp.set(bezierPoint(acr1.x, ctl1.x, ctl2.x, acr2.x, ratio),

          bezierPoint(acr1.y, ctl1.y, ctl2.y, acr2.y, ratio));

  itpCtl1.set(lerp(acr1.x, ctl1.x, ratio),

              lerp(acr1.y, ctl1.y, ratio));

  itpCtl2.set(lerp(itpCtl1.x, lerp(ctl1.x, ctl2.x, ratio), ratio),

              lerp(itpCtl1.y, lerp(ctl1.y, ctl2.y, ratio), ratio));

}

​

void drawItpBezier() {

  //Bezier curve

  stroke(0, 0, 255);

  strokeWeight(10);

  point(itp.x, itp.y);

  strokeWeight(5);

  bezier(itp.x, itp.y, itpCtl2.x, itpCtl2.y, itpCtl1.x, itpCtl1.y, acr1.x, acr1.y);

}

​

void drawBaseBezier() {

  //Control points

  stroke(255, 0, 0);

  strokeWeight(10);

  point(ctl1.x, ctl1.y);

  point(ctl2.x, ctl2.y);

  //Handle

  strokeWeight(5);

  line(ctl1.x, ctl1.y, acr1.x, acr1.y);

  line(ctl2.x, ctl2.y, acr2.x, acr2.y);

  //Bezier curve

  stroke(0);

  strokeWeight(2.5);

  bezier(acr1.x, acr1.y, ctl1.x, ctl1.y, ctl2.x, ctl2.y, acr2.x, acr2.y);

}

​

void draw() {

​

  ratio = float(mouseX)/width;

  updateItpBezier();

​

  background(255);

​

  translate(width*.5, height*.5);

  drawBaseBezier();

  drawItpBezier();

}

​

void keyPressed(){

  if(key == 'r'){

    initBezier();

  }

}

​

​