Trigonometry02

private int reddish;

private int greenish;

private int blueish;

​

​

public void setup() {

  size(800, 600);

  noFill();

  reddish = color(204, 51, 0);

  greenish = color(102, 153, 51);

  blueish = color(51, 102, 153);

}

​

void sineCircle(float x, float y, float radius, float period, float amplitude, float rotations) {

  pushStyle();

  pushMatrix();

​

  strokeWeight(8);

​

  translate (x, y);

​

  int stepsPerCircle=100;

​

  float circleStepAngle = TWO_PI/stepsPerCircle;

  int stopValue = round(rotations*stepsPerCircle);

  float waveStepAngle = period*circleStepAngle;

  for (int i = 0; i < stopValue; i++) {

    int myColor = lerpColor (reddish, greenish, (float)i/stopValue);

    stroke(myColor);

    float shift = amplitude*sin(i*waveStepAngle);

    point (radius+shift, 0);

    rotate (circleStepAngle);

  }

​

  popMatrix();

  popStyle();

}

​

void sineLine(float period, float amplitude) {

  pushStyle();

  pushMatrix();

​

  strokeWeight(3);

​

  translate (0, height/2);

​

  for (int x = 0; x < width; x+=5) {

    int alpha = (int)map (abs(x-width/2), 0, width/2, 32, 255);

    stroke (blueish, alpha);

    float angle = map (x, 0, width, 0, TWO_PI*period);

    float shift = amplitude*sin(angle);

    point (x, shift);

  }

​

  popMatrix();

  popStyle();

}

​

​

public void draw() {

  background(32);

​

  float period = map (mouseX, 0, width, 1f, 10f);

  float amplitude = map (mouseY, 0, height, min(height, width) / 24f, min(height, width) / 6f);

  sineLine(period, amplitude);

  sineCircle(width/2, height/2, min(height, width)/3f, round(period), amplitude, 1f);

}

​