E. processus - OpenProcessing

mySketch
xxxxxxxxxx
 
//Escherichia processus;
​
ArrayList<Colony> colonies = new ArrayList<Colony>();
​
void setup() {
  //size(960, 540);
  fullScreen();
​
  colorMode(HSB, 360, 100, 100);
}
​
void draw() {
  background(map(mouseX, 0, width, 0, 360), map(mouseY, 0, height, 20, 40), 20);
​
  for (Colony colony : colonies) {
    colony.update();
  }
}
​
void mouseClicked() {
  colonies.add(new Colony(new PVector(mouseX, mouseY)));
}
​
class Colony {
  ArrayList<Bacteria> members = new ArrayList<Bacteria>();
​
  PVector target;
​
  Colony(PVector _target) {
    target = _target;
    members.add(new Bacteria(target.x + random(-20, 20), target.y + random(-20, 20)));
  }
​
  void update() {
​
    for (int i = 0; i < members.size(); i++) {
      Bacteria single = members.get(i);
​
      single.run(members, target);
​
      if (single.isDead()) {
        members.remove(i);
      }
    }
​
    move();
  }
​
  void move() {
    target.add(new PVector(noise(width, millis()), noise(height, millis())));
​
    if (target.x > width) {
      target.x = 0;
    } else if (target.x < 0) {
      target.x = width;
    }
​
    if (target.y > height) {
      target.y = 0;
    } else if (target.y < 0) {
      target.y = height;
    }
  }
}
​
class Bacteria {
​
  PVector location;
  PVector velocity;
  PVector acceleration;
​
  int lifespan = 250 + int(random(-50, 50));
  int size = 16;
​
  float maxSpeed = 3;
  float maxForce = 0.2;
​
  Bacteria(float posX, float posY) {
    location = new PVector(posX, posY);
    velocity = new PVector(random(-2, 2), random(-2, 2));
    acceleration = new PVector(0, 0);
  }
​
  void run(ArrayList<Bacteria> colony, PVector target) {
    checkEdges();
    divide(colony);
    applyBehaviors(colony, target);
​
    update();
​
    display();
  }
​
  void update() {
    velocity.add(acceleration);
    velocity.limit(maxSpeed);
    location.add(velocity);
    acceleration.mult(0);
​
    lifespan --;
  }
​
  void display() {
    stroke(map(mouseX, 0, width, 360, 0), 80, 100);
    fill(map(mouseX, 0, width, 360, 0), 80, 100, 100);
    ellipse(location.x + map(noise(velocity.x, millis() * 0.001), 0, 1, -5, 5), 
      location.y + map(noise(velocity.y, millis() * 0.001), 0, 1, -5, 5), 
      size, 
      size);
  }
​
  void checkEdges() {
    if (location.x > width - size) {
      location.x = width - size;
    } else if (location.x < size) {
      location.x = size;
    }
​
    if (location.y > height - size) {
      location.y = height - size;
    } else if (location.y < size) {
      location.y = size;
    }
  }
​
  void divide(ArrayList<Bacteria> colony) {
​
    float probPopulation = noise(millis() * 0.1) / colony.size();
    if (random(1) < probPopulation) {
      colony.add(new Bacteria(location.x, location.y));
    }
  }
​
  void applyBehaviors(ArrayList<Bacteria> colony, PVector target) {
    PVector separateForce = separate(colony);
    PVector seekForce = seek(target);
    PVector mouseRepelForce = avoidMouse(new PVector(mouseX, mouseY));
    separateForce.mult(2);
    seekForce.mult(1);
    mouseRepelForce.mult(3);
    acceleration.add(separateForce);
    acceleration.add(seekForce);
    acceleration.add(mouseRepelForce);
  }
​
  PVector seek(PVector target) {
    PVector desired = PVector.sub(target, location);
​
    desired.normalize();
    desired.mult(maxSpeed);
​
    PVector steer = PVector.sub(desired, velocity);
    steer.limit(maxForce);
​
    return steer;
  }
​
  PVector separate(ArrayList<Bacteria> colony) {
    float desiredSeparation = size + 2;
    PVector sum = new PVector();
    int count = 0;
​
    for (Bacteria other : colony) {
      float d = PVector.dist(location, other.location);
      if ((d > 0) && (d < desiredSeparation)) {
        PVector diff = PVector.sub(location, other.location);
        diff.normalize();
        diff.div(d);
        sum.add(diff);
        count++;
      }
    }
​
    if (count > 0) {
      sum.div(count);
      sum.normalize();
      sum.mult(maxSpeed);
​
      sum.sub(velocity);
      sum.limit(maxForce);
    }
    return sum;
  }
​
  PVector avoidMouse(PVector mousePos) {
    float desiredSeparation = 50;
    PVector sum = new PVector();
​
    float d = PVector.dist(location, mousePos);
    if ((d > 0) && (d < desiredSeparation)) {
      PVector diff = PVector.sub(location, mousePos);
      diff.normalize();
      diff.div(d);
      sum.add(diff);
​
      sum.normalize();
      sum.mult(maxSpeed);
​
      sum.sub(velocity);
      sum.limit(maxForce);
    }
​
    return sum;
  }
​
  boolean isDead() {
    if (lifespan < 0) {
      return true;
    } else {
      return false;
    }
  }
}