Neon Trails - OpenProcessing

mySketch
xxxxxxxxxx
 
ArrayList<Particle> p = new ArrayList();
int num=20,cM=360;
PVector tar=new PVector(), tmp;
float tx, ty;
boolean show=false;
​
void setup() {
  size(600, 600);
  tmp=new PVector(width/2, height/2);
  colorMode(HSB, cM);
  background(0);
​
  for (int i = 0; i < num; i++) {
    p.add(new Particle(random(width), random(height)));
  }
} 
​
void draw() {
  //background(0);
  fill(0, 40);
  noStroke();
  rect(0, 0, width, height);
​
  tx=width/2;
  ty=height/2;
​
  tar=new PVector(0, 0);
  for (int i=0; i<p.size(); i++) {
    for (int j=i+1; j<p.size(); j++) {
      float r = dist(p.get(i).pos.x, p.get(i).pos.y, p.get(j).pos.x, p.get(j).pos.y);
      float pot = potential(r, random(.25, .75));
      float potX= pot*(p.get(j).pos.x-p.get(i).pos.x)/r;
      float potY= pot*(p.get(j).pos.y-p.get(i).pos.y)/r;
      tar.x+=potX;
      tar.y+=potY;
    }
    float r = dist(p.get(i).pos.x, p.get(i).pos.y, tx, ty);
    float pot = potential(r, 2);
    float potX= pot*(tx-p.get(i).pos.x)/r;
    float potY= pot*(ty-p.get(i).pos.y)/r;
​
    tar.x+=potX;
    tar.y+=potY;
  }
  tar.mult(.01);
  tmp.add(tar);
  for (int i = 0; i < p.size(); i++) {
    p.get(i).move();
    p.get(i).display();
  }
  if (show) {
    noStroke();
    fill(360);
    ellipse(tmp.x, tmp.y, 6, 6);
  }
}
​
void mousePressed() {
  if (mouseButton==RIGHT) {
    show=!show;
  }
}
​
float potential(float rT, float mT) {
  return 1000000*mT/pow((rT+100), 2);
}
​
class Particle {
  PVector pos;
  PVector vel;
  PVector acc;
  float hue, variation, speed, maxSpeed;
  ArrayList<Point> history;
  int maxSize=10, hueDif=50;
​
  Particle(float x, float y) {
    pos = new PVector(x, y);
    vel = PVector.random2D();
    vel.mult(10);
    acc = new PVector(0, 0);
    history = new ArrayList();
​
    hue = map(200,0,360,0,1);
​
    variation = random(0.75, 1);
    speed = random(0.25, 0.75);
    maxSpeed = random(7, 10);
  }
  void move() {
    PVector steer = new PVector(tmp.x, tmp.y);
    steer.sub(pos);
    steer.normalize();
    steer.mult(speed*variation);
    acc.add(steer);
​
    vel.add(acc);
    vel.limit(maxSpeed);
    pos.add(vel);
    acc.mult(0);
    history.add(new Point(new PVector(pos.x, pos.y), vel));
​
    if (history.size() > 20) {
      history.remove(0);
    }
  }
​
  void display() {
​
    strokeWeight(4);
    beginShape();
    for (int i=history.size()-1; i>0; i--) {
      float h = map(hue,0,1,0,cM);
      stroke(h, cM, cM, 100);
      fill(h, cM, cM);
      float w=map(i, history.size(), 0, maxSize, 0)/1.75;
      float a=history.get(i).vel.heading();
      if (i==history.size()-1) {
        a=vel.heading();
        vertex(pos.x+(w*cos(a+radians(-90))), pos.y+(w*sin(a+radians(-90))));
        vertex(pos.x+((vel.mag()*1.75)*cos(a)), pos.y+((vel.mag()*1.55)*sin(a)));
        vertex(pos.x+(w*cos(a+radians(90))), pos.y+(w*sin(a+radians(90))));
        curveVertex(pos.x+(w*cos(a+radians(90))), pos.y+(w*sin(a+radians(90))));
      }
      curveVertex(history.get(i).loc.x+(w*cos(a+radians(90))), history.get(i).loc.y+(w*sin(a+radians(90))));
    }
    for (int i=0; i<history.size(); i++) {
      float w=map(i, history.size(), 0, maxSize, 0)/1.75;
      float a=history.get(i).vel.heading();
      curveVertex(history.get(i).loc.x+(w*cos(a+radians(-90))), history.get(i).loc.y+(w*sin(a+radians(-90))));
      if (i==history.size()-1) {
        a=vel.heading();
        curveVertex(pos.x+(w*cos(a+radians(-90))), pos.y+(w*sin(a+radians(-90))));
        vertex(pos.x+(w*cos(a+radians(-90))), pos.y+(w*sin(a+radians(-90))));
      }
    }
    endShape(CLOSE);
​
    if (dist(pos.x, pos.y, tmp.x, tmp.y) < 100) {
      hue += .005;
      if (hue > 1) {
        hue = 0;
      }
    }
  }
}
​
class Point {
  PVector loc=new PVector();
  PVector vel=new PVector();
​
  Point(PVector L, PVector v) {
    loc=L;
    vel=v;
  }
}