Wheel of Lunch

class Wedge {

  String nom;

  int fColor, sColor, tColor;

  float tScale;

  Wedge(String nom, int fColor, int sColor, int tColor, float tScale) {

    this.nom = nom;

    this.fColor = fColor;

    this.sColor = sColor;

    this.tColor = tColor;

    this.tScale = tScale;

  }

};

​

int[] myFColors = {#b9a998, #103787, #46c304, #f27c0d, #f3131b, #0673e6};

int[] mySColors = {#bFbFbF, #3F3FbF, #7FfF3F, #fF7F3F, #fF3F3F, #3F7FfF};

int[] myTColors = {#f3131b, #f27c0d, #f3131b, #103787, #46c3d4, #fbd90c};

​

int nbrWedges;

ArrayList<Wedge> wedges;

int curSlot = -1, lastSlot = -1;

float iRadius=80;

float oRadius=275;

float INITVA = 0.17;

float DAMPING = 0.985;

float MAGNET = .0125;

float rotation = random(TWO_PI);

float angularVelocity = INITVA;

PImage bgImg, crankImg;

Boolean isDragging = false;

Boolean slowTrigger = false;

long slowTriggerStart;

​

void setup() {

  size(700,700);

  smooth();

  crankImg = loadImage("crank1.png");

  bgImg = loadImage("hub_bg.png");

  frameRate(24);

  preloadWedges();

  textFont(createFont("Helveetica",24));

}

​

void draw() {

  background(255);

  pushMatrix();

    translate(width/2, height/2);

    image(bgImg,-bgImg.width/2, -bgImg.height/2);

    pushMatrix();

      rotate(rotation);

      drawWheel();

    popMatrix();

  popMatrix();

​

  if (curSlot >= 0) {

    Wedge w = wedges.get(curSlot);

    pushMatrix();

    float topMargin = 40;

    float lineHeight = 22;

    translate(width/2-340,0);

    fill(#071f9e);

    noStroke();

    textAlign(LEFT,BASELINE);

    text(w.nom,0,topMargin);

    textSize(18);

    fill(#6dd0fd);

    popMatrix();

  }

  doPhysics();

​

}

​

void preloadWedges() {

   String[] preloadStrings = {"SKIP LUNCH","Burgers","Boring Salad","비빔밥 Bimbimbap","Taco Truck","Chinese",

                              "SPIN AGAIN!","Indian Buffet","Hipster Food Truck","That Hole-in-the-wall","Drive-thru","Brew-pub",

                              "INVITE ONE MORE", "Ice Cream?","Thai Food","Delicatessen","Sub shop","Pizza",

                              "SPIN AGAIN","Ramen","Fish + Chips + Beer","Sushi","Phở","50's Diner",

                              "VENDING MACHINE","BBQ Joint","Panini","Food Court","Shawarma"};

   int cidx = 0;

   float labelWidth = (oRadius-iRadius)-18;

   wedges = new ArrayList<Wedge>();

   // console.log("Allocating wedges");

   textSize(24);

   for (int i = 0; i < preloadStrings.length; ++i) {

     int sColor,fColor,tColor;

     if (i % 6 == 0) {

       fColor = (i/6)%2 == 0? #000000 : #FFFF00;

       sColor = (i/6)%2 == 0? #444444 : #FFFF00;

       tColor = (i/6)%2 == 0? #FFFFFF : #000000;

     } else {

       fColor = myFColors[cidx];

       sColor = mySColors[cidx];

       tColor = myTColors[cidx];

       cidx += 1;

       cidx %= myFColors.length;

     }

     String nom = preloadStrings[i];

     float tScale = min(1,labelWidth/textWidth(nom));

     wedges.add(new Wedge(nom, fColor, sColor, tColor, tScale));

   }

   // console.log(wedges.size() + " added");

​

}

​

void drawWheel() {

  int nbrWedges = wedges.size();

  float wedgeAngle = 2*PI/nbrWedges;

  float tAngle = -wedgeAngle/2;

  float bAngle = wedgeAngle/2;

  float textCenterX = (iRadius+oRadius)/2;

  textAlign(CENTER,CENTER);

  textSize(24);

​

  if (!slowTrigger && angularVelocity < .001) {

    slowTrigger = true;

    slowTriggerStart = millis();    

  }

​

  for (int i = 0; i < nbrWedges; ++i) {

    Wedge biz = wedges.get(i);

    if (i == curSlot) {

        fill(255);

        stroke(255);

    } else {

        fill(biz.fColor);

        stroke(biz.sColor);

    }

    pushMatrix();

        rotate(wedgeAngle*i);

        strokeWeight(4);

        beginShape();

        vertex(cos(tAngle)*iRadius,sin(tAngle)*iRadius);

        vertex(cos(tAngle)*oRadius,sin(tAngle)*oRadius);

        vertex(cos(bAngle)*oRadius,sin(bAngle)*oRadius);

        vertex(cos(bAngle)*iRadius,sin(bAngle)*iRadius);

        endShape(CLOSE);

        strokeWeight(1);

        float tScale = biz.tScale;

        if (i == curSlot) {

            fill(0);

            if (slowTrigger) {

                tScale += (sin(millis()*.002) * 0.2) * constrain(map(millis()-slowTriggerStart,0,2000,0,1),0,1);

            }

        } else {

            fill(biz.tColor);

            stroke(biz.tColor);

        }

        pushMatrix();

            translate(textCenterX,0);

            scale(tScale);

            text(biz.nom,0,0);

        popMatrix();

        rotate(bAngle);

        image(crankImg, oRadius,-crankImg.height/2);

    popMatrix();

  }

}

​

void doPhysics() {

  int nbrWedges = wedges.size();

  float wedgeAngle = 2*PI/nbrWedges;

  curSlot = (int) ((nbrWedges-Math.floor((rotation+wedgeAngle/2)/wedgeAngle)) % nbrWedges);

  rotation += angularVelocity;

​

  if (rotation > TWO_PI)

    rotation -= TWO_PI;

​

  float da = TWO_PI-curSlot*wedgeAngle;

  float delta = da - rotation;

  if (delta > PI)

    delta -= TWO_PI;

  if (delta < -PI)

    delta += TWO_PI;

  if (!isDragging) {

    angularVelocity += delta*MAGNET;

    angularVelocity *= DAMPING;

  }

  if (curSlot != lastSlot) {

    // clickSnd.play();  Play wheel click noise here...

    lastSlot = curSlot;

  }

}

​

float lastVelocity;

​

void mouseDragged() {

    newVelocity = atan2(mouseY-height/2,mouseX-width/2) - atan2(pmouseY-height/2,pmouseX-width/2);

    if (!isDragging) {

      isDragging = true;

      lastVelocity = newVelocity;

      slowTrigger = false;

    }

    angularVelocity = (newVelocity + lastVelocity)/2;

    console.log("drag!");

}

​

void mouseReleased() {

  isDragging = false;

  slowTrigger = false;

}