The Horde Shooter - OpenProcessing

Shooter
Button
Gun
Obj
Rain
Splash
Target
FlyingTarget
xxxxxxxxxx
 
//Objects
private ArrayList<Obj> targets, splashes, flyers, rain;
private ArrayList<Integer> scores;
private ArrayList<ArrayList<Obj>> allObjects;
private Gun gun;
​
//GameData
private int score,time,gameStage,lives;
final int FULL_AMMO=8, NUM_TARGETS=3, NUM_FLYING_TARGETS=2, RAIN_DENSITY=30;
​
//Images
private PImage backScreen,bloodyScreen,splash;
​
void setup(){
  size(800,550);
  frameRate(60);
  targets = new ArrayList<Obj>();
  splashes = new ArrayList<Obj>();
  flyers = new ArrayList<Obj>();
  rain = new ArrayList<Obj>();
  while(rain.size()<RAIN_DENSITY){
      rain.add(new Rain());
  }
  scores = new ArrayList<Integer>();
  while(targets.size()<NUM_TARGETS){
      targets.add(new Target());
  }
  while(flyers.size()<NUM_FLYING_TARGETS){
      flyers.add(new FlyingTarget());
  }
  allObjects = new ArrayList<ArrayList<Obj>>();
  allObjects.add(targets);
  allObjects.add(flyers);
  allObjects.add(rain);
  allObjects.add(splashes);
  scores.add(0);
  backScreen = loadImage("background.jpg");
  bloodyScreen = loadImage("bloodyScreen.png");
  splash = loadImage("splash.png");
  lives = 5;
  gun = new Gun();
  noCursor();
  gameStage=0;
}
​
String highScore(){
  int highScore=scores.get(0);
  for(int i=1;i<scores.size();i++)
    if(scores.get(i)>highScore) highScore=scores.get(i);
  if(highScore==0) return "---";
  return ""+highScore;
}
​
​
String getLivesTally(){
  String mo="";
  for(int i=0; i<lives; i++)
    mo+="|";
  return mo;
}
​
​
void menu(){
  imageMode(CENTER);
  image(backScreen,width/2,height/2);
  image(bloodyScreen,width/2,height/2,width,height);
  fill(255);
  textSize(60);
  text("High Score\n"+highScore(),width/2,85);
  fill(255,0,0);
  textSize(120);
  text("THE HORDE",width/2,250);
  Button playButton = new Button("PLAY",width/2,height-200);
  Button rulesButton = new Button("DIRECTIONS",width/2,height-150);
  playButton.update(); 
  rulesButton.update();
  if(gun.getAmmo()>=0 && gameStage==0){
    if(playButton.isPressed()){
      gameStage=1;
      gun.reload(FULL_AMMO);
      frameCount=0;
      score=0;
      lives=5;
      for(Obj t : targets){
        ((Target)t).sendToBackPosition();
      }
    }
    if(rulesButton.isPressed()){
      gameStage=4;
      gun.reload(FULL_AMMO);
    }
  }
  gun.update();
  gun.display();
}
​
​
void howToPlay(){
  Button back = new Button("Okay!",width/2,150);
  image(backScreen,width/2,height/2);
  fill(255);
  back.update();
  textSize(20);
  fill(255);
  text("use your crosshair to aim at the zombies",gun.getX(),gun.getY()-20);
  text("use MOUSE1 to shoot",gun.bx,gun.by-100);
  textSize(30);
  fill(255,0,0);
  text("we will keep track of the number of zombies you kill",width/2,100);
  fill(255);    
  text("You have 10 lives",width/2,50);
  if(back.isPressed() && gun.getAmmo()>=0 && gameStage==4){
    gameStage=0;
    gun.reload(FULL_AMMO);
  }  
  gun.update();
  gun.display();
}
​
​
void gameScreen(){
  background(0);
  tint(255);
  image(backScreen,width/2-mouseX/10+width/20,height/2-mouseY/10);
  
  //display objects
  gun.update();
  for(ArrayList<Obj> list : allObjects){
    for(Obj obj : list){
      obj.update();
      obj.display();
    } 
  }
  gun.display();
  
  //display kills
  textSize(50);
  fill(255);
  text("KILLS",100,110);
  textSize(100);
  fill(255,0,0);
  text(score,100,90);
  
  //diplay lives
  textSize(50);
  fill(255);
  text("LIVES",width-150,60);
  fill(255,0,0);
  text(lives+" "+getLivesTally(),width-150,90);
  
  //display timer
  fill(255);  
  textSize(40);
  text((int)time,width/2,50);
  time=(int)frameCount/60;
  if(lives<=0) gameStage=3;
}
​
​
void endScreen(){ 
  image(backScreen,width/2,height/2);
  image(bloodyScreen,width/2,height/2,width,height);
  fill(255,0,0);
  textSize(150);
  text("YOU DIED",width/2,200);
  
  fill(255);
  textSize(40);
  text("You killed "+score+" zombies in "+(int)time+" seconds",width/2,300);
  
  textSize(30);
  text("Thank you for playing!",width/2,35);
  scores.add(score);
  Button p = new Button("CONTINUE",width/2,height/2+50);
  p.update();
  p.display();
  gun.update();
  gun.display();
  if(p.isPressed()&& !(gun.getAmmo()<=0) && gameStage==3){
    gameStage=0;
    gun.reload(FULL_AMMO);
  }  
}
​
​
void draw(){
  if(gameStage==0) menu();
  if(gameStage==1) gameScreen();
  if(gameStage==3) endScreen();
  if(gameStage==4) howToPlay();
  for(int i=0;i<targets.size();i++){
    if(((Target)targets.get(i)).getSize()>255){
       splashes.add(new Splash(splash,targets.get(i).getX(),targets.get(i).getY()));
       targets.remove(i);
       targets.add(new Target());
       lives--;
    }
  }
  for(int i=0;i<flyers.size();i++){
    if(((Target)flyers.get(i)).getSize()>255){
       splashes.add(new Splash(splash,flyers.get(i).getX(),flyers.get(i).getY()));
       flyers.remove(i);
       flyers.add(new FlyingTarget());
       lives--;
    }
  }
}
​
​
void mousePressed(){
  gun.incrementAmmo();
  if(gun.getAmmo()>=0){
    for(int i=0;i<targets.size();i++){
      Target t = ((Target)targets.get(i));
      double distance = (Math.sqrt((t.getX()-mouseX)*(t.getX()-mouseX)+(t.getY()-mouseY)*(t.getY()-mouseY)));
      
      if(distance<=t.getSize()/2 && gameStage==1){      
        fill(255);
        score++;
        targets.remove(i);
        targets.add(new Target());
        i--;  
      } 
    }
    for(int i=0;i<flyers.size();i++){
      Target t = ((Target)flyers.get(i));
      double distance = (Math.sqrt((t.getX()-mouseX)*(t.getX()-mouseX)+(t.getY()-mouseY)*(t.getY()-mouseY)));
      
      if(distance<=t.getSize()/2 && gameStage==1){      
        fill(255);
        score++;
        flyers.remove(i);
        flyers.add(new FlyingTarget());
        i--;  
      } 
    }
  }
}
​
​
void keyPressed(){
  if(keyCode=='R'){
    gun.reload(FULL_AMMO);
    gameStage=0;
  }
  if(keyCode==LEFT) gameStage--;
}