Wavy doodle - OpenProcessing

mySketch
xxxxxxxxxx
 
final int nb = 80;
float rad = 80;
float deltaRad = 11;
float rot = 0, rotSpeed = .04;
​
int mode = 0;
​
void setup() {
  size(450, 450, P2D);
  noFill();
  stroke(220);
  strokeWeight(2);
}
​
void draw() {
  background(0);
  translate(width/2, height/2);
​
  rot += rotSpeed;
  rot %= TWO_PI;
​
  doThis(frameCount/20.0);
  doThis(frameCount/20.0 + PI);
}
​
void doThis(float omega) { 
  beginShape();
  float deltaTheta = 0;
  int nbCycles = 6;
  float spreadAngle = 1.8;
  for (int i = 0; i <= nb; i ++) {
    float theta = i * TWO_PI/nb;
    float dr = (theta - rot);
    if (dr > PI) {
      dr = TWO_PI-dr;
    } else if (dr < -PI) {
      dr = TWO_PI+dr;
    }
​
    if (abs(dr) > spreadAngle) {
      deltaTheta = 0;
    } else {
      deltaTheta = map(abs(dr), 0, spreadAngle, 1, 0);
    }
​
    float deltaRadCoeff = deltaTheta * cos(omega + map(i, 0, nb, 0, nbCycles*TWO_PI));
    if (mode == 0) {
      float r = rad + deltaRad * deltaRadCoeff; 
      vertex(r * cos(theta), r * sin(theta));
    } else if (mode == 1) {
      float x, y;
      if (i < nb/4) {
        deltaRadCoeff *= cos(map(i, 0, nb/4, -PI/2, PI/2));
        x = map(i, 0, nb/4, -rad, rad);
        y = -rad + deltaRadCoeff * deltaRad;
      } else if (i < nb/2) {
        deltaRadCoeff *= cos(map(i, nb/4, nb/2, -PI/2, PI/2));
        x = rad + deltaRadCoeff * deltaRad;
        y = map(i, nb/4, nb/2, -rad, rad);
      } else if (i < 3*nb/4) {
        deltaRadCoeff *= cos(map(i, nb/2, 3*nb/4, -PI/2, PI/2));
        x = map(i, nb/2, 3*nb/4, rad, -rad);
        y = rad + deltaRadCoeff * deltaRad;
      } else {
        deltaRadCoeff *= cos(map(i, 3*nb/4, nb, -PI/2, PI/2));
        x = -rad + deltaRadCoeff * deltaRad;
        y = map(i, 3*nb/4, nb, rad, -rad);
      }
      vertex(x, y);
    }
  } 
  endShape();
}
​
void mousePressed(){
  mode = (mode+1)%2; 
}
​