attractors - OpenProcessing

mySketch
xxxxxxxxxx
 
Mover[] movers = new Mover[300]; //array of movers
Attractor[] attractors = new Attractor[10]; //array of attractors
float t = 10; 
​
void setup() {
  fullScreen();
  for (int i=0; i<movers.length;i++) {
     movers[i] = new Mover(3, random(width), random(height));
  }
  for (int j=0; j<attractors.length;j++) {
    attractors[j] = new Attractor(10, 0.3, random(width), random(height));
  }
}
​
void draw() {
  //opacity background for tails-effect
  fill(33, 10);
  rect(0, 0, width, height);
  
  noiseDetail(10);
  float p = map(noise(t), 0, 1, -0.05, 0.05);
  PVector wind = new PVector(p, 0);
  
  for (int i=0; i< movers.length; i++) { 
    for (int j=0; j<attractors.length; j++) {
      PVector force = attractors[j].attract(movers[i]);
      movers[i].applyForce(force);
    }
    movers[i].applyForce(wind);
    movers[i].update();
    movers[i].display();
  }
  t += 0.001;
}
​
class Attractor {
  float mass;
  float G;
  PVector location;
  
  Attractor(float m, float g, float x, float y) {
    mass = m;
    G = g;
    location = new PVector(x, y);
  }
  
  PVector attract(Mover mover) {
    PVector force = PVector.sub(location, mover.location);
    float distance = force.mag();
    distance = constrain(distance, 15, 25);
    
    force.normalize();
    float strength = (G * mass * mover.mass) / (distance * distance);
    force.mult(strength);
  
    return force;
  }
}
​
class Mover {
  PVector location;
  PVector velocity;
  PVector acceleration;
  float mass;
  float maxSpeed = random(3, 6);
    
  Mover(float m, float x, float y) {
    location = new PVector(x, y);
    velocity = new PVector(0, 0);
    acceleration = new PVector(0, 0);
    mass = m;
  }
  
  void applyForce(PVector force) {
    PVector f = PVector.div(force, mass);
    acceleration.add(f);
  }
  
  void update() {
    velocity.add(acceleration);
    velocity.limit(maxSpeed);
    location.add(velocity);
    acceleration.mult(0);
  }
  
  void display() {
    fill(203, 247, 226); 
    noStroke();
    ellipse(location.x, location.y, mass, mass);
  }
}