Rectangular subdivision drawn with a pencil on paper

mySketch
xxxxxxxxxx
 
int numSegs = 40;
boolean horiz;
​
​
void setup() {
  size(550, 600);
  noLoop();
}
​
void draw() {
  background(255);
  stroke(0, 150);
  strokeWeight(2);
  noFill();
  rect(0, 0, width-1, height-1);
  drawPaper();
  subDivide(5, 50, 50, width-100, height-100);
}
​
​
void subDivide(int n, float x, float y, float w, float h) {
  if (n==0) {
    noFill();
    drawRect(x, y, w, h);
    boolean linesHoriz =  random(1) > 0.5 ? true : false;
    float limitW = random(w);
    float limitH = random(h);
    if (linesHoriz) {
      for (float j = y; j < (h+y); j+=5) {
        drawLine(x, j, x + limitW, j, false);
      }
    } else {
      for (float i = x; i < (w+x); i+=5) {
        drawLine(i, y, i, y + limitH, false);
      }
    }
  } else {
    float t = random(1);
    boolean horiz =  random(1) > 0.5 ? true : false;
    if (horiz) {
      subDivide(n-1, x, y, w, h*t);
      subDivide(n-1, x, y+h*t, w, h*(1-t));
    } else {
      subDivide(n-1, x, y, w*t, h);
      subDivide(n-1, x+w*t, y, w*(1-t), h);
    }
  }
}
​
void drawLine(float strtx, float strty, float finx, float finy, boolean isShape) { 
  float fraction = 0;
  int  divBy = numSegs;
  float x1 = strtx;
  float y1 = strty;
  for (int j = 0; j <= int (numSegs); j++) {
    float x = (randomGaussian()*.3)+x1 + (fraction * (finx-x1));
    float y = (randomGaussian()*.3)+y1 + (fraction * (finy-y1));
    if (isShape) { 
      strokeWeight(.5); // leave separate for tweaking purposes
      stroke(80);
      vertex(x, y);
    } else {
      strokeWeight(.5);
      stroke(80);
      line(x1, y1, x, y);
    }
    x1 = x;
    y1 = y;
    fraction = 1.0/divBy--;
  }
}
​
​
void drawRect(float x, float y, float w, float h) {
  beginShape();
  drawLine(x, y, x+w, y, true);
  drawLine(x+w, y, x+w, y+h, true);
  drawLine( x+w, y+h, x, y+h, true);
  drawLine( x, y+h, x, y, true);
  endShape();
}
​
​
void drawPaper() {
  noStroke();
  for (int i = 0; i < width; i += 2) {
    for (int j = 0; j < height; j += 2) {
      fill(random(210, 235), 150);
      rect(i, j, 2, 2);
    }
  }
  for (int i = 0; i < 50; i++) {
    fill(random(70, 110), 140);
    ellipse(random(0, width), random(0, height), random(1, 3), random(1, 3));
  }
}
​
void mousePressed() {
  redraw();
}
​