Coronavirus simulation 3d - OpenProcessing

main.java
person.java
button.java
xxxxxxxxxx
 
/*
Coronavirus simulation 3d
​
Roughly simulates an outbreak using different social distances.
Play around with the variables at the top to explore how it can spread in different environments.
​
Inspired by this article:
https://www.washingtonpost.com/graphics/2020/world/corona-simulator/?fbclid=IwAR1tGUaApSRIXYCArDRx3kra6xkTNUkh4k4EWonp0d0XOvU2P9z7pVqiOcQ
​
Author:
  Jason Labbe
​
Site:
  jasonlabbe3d.com
*/
​
int population = 200;
float personSize = 8;
int recoveryTime = 400;
float deathChance = 7; // Out of 100%
float socialDistance = 0; // Out of 100%
​
float _canvas = 700;
float _bounds = 200;
float _zoomAmount = 200;
boolean _collisions = true;
ArrayList<Person> _people = new ArrayList<Person>();
ArrayList<Button> _buttons = new ArrayList<Button>();
​
int _normalCount = 0;
int _sickCount = 0;
int _recoveryCount = 0;
int _deathCount = 0;
int _socialDistanceCount = 0;
int _days = 0;
​
color _normalColor;
color _sickColor;
color _recoveryColor;
color _deadColor;
​
final int NORMAL = 0;
final int SICK = 1;
final int RECOVER = 2;
final int DEAD = 3;
​
​
void setup() {
  size(_canvas, _canvas, P3D);
  
  hint(DISABLE_DEPTH_TEST);
  textFont(loadFont("Arial Bold", 24));
  
  _normalColor = color(80, 200, 80);
  _sickColor = color(210, 200, 0);
  _recoveryColor = color(203, 138, 192);
  _deadColor = color(255, 50, 50);
  
  Button noDistButton = Button.create("No social distance", width - 160, 15, 150, 25);
  noDistButton.registerClickEvent(noDistTriggered);
  
  Button lowDistButton = Button.create("Low social distance", width - 160, 50, 150, 25);
  lowDistButton.registerClickEvent(lowDistTriggered);
  
  Button highDistButton = Button.create("High social distance", width - 160, 85, 150, 25);
  highDistButton.registerClickEvent(highDistTriggered);
  
  resetSim();
}
​
void mouseClicked() {
  Button.checkClickEvent()
}
​
void draw() { 
  pushMatrix();
    background(255);
  
    translate(_canvas / 2, _canvas / 2, _canvas / 2 - _zoomAmount);
​
    rotateY(radians(map(mouseX, 0, width, -180, 180)));
    rotateX(radians(map(mouseY, 0, height, 180, -180)));
  
    pointLight(200, 200, 200, 35, 1000, 36);
    ambientLight(102, 102, 102);
  
    displayContainer();
  
    for (int i = 0; i < _people.size(); i++) {
      _people.get(i).move();
      _people.get(i).display();
    }
  popMatrix();
  
  displayStats();
  displayGraph();
  
  if (_sickCount == 0) {
    displayEnd();
  } else {
    _days = int(frameCount / 24);
  }
  
  for (int i = 0; i < _buttons.size(); i++) {
    _buttons.get(i).display();
  }
}
​
void mouseScrolled() {
  float delta = 50;
  if (mouseScroll > 0) {
    _zoomAmount -= delta;
  } else {
    _zoomAmount += delta;
  }
}
​
void resetSim() {
  frameCount = 0;
  _people.clear();
  _normalCount = population;
  _sickCount = 0;
  _recoveryCount = 0;
  _deathCount = 0;
  _socialDistanceCount = 0;
  _days = 0;
  
  for (int i = 0; i < population; i++) {
    Person person = new Person(random(_bounds), random(_bounds), random(_bounds));
    _people.add(person);
    
    if (i / population * 100 < socialDistance) {
      person.practiceSocialDistance();
    }
  }
  
  // Patient zero doesn't practice social distancing.
  for (int i = 0; i < _people.size(); i++) {
    if (!_people.get(i).socialDistance) {
      _people.get(i).setState(SICK);
      break;
    }
  }
}
​
void displayContainer() {
  noFill();
  stroke(0);
  strokeWeight(1);
​
  pushMatrix();
    translate(-_bounds / 2, _bounds / 2, -_bounds / 2);
    rotateX(radians(90));
    rect(0, 0, _bounds, _bounds);
  popMatrix();
  
  pushMatrix();
    translate(-_bounds / 2, -_bounds / 2, -_bounds / 2);
    rotateX(radians(90));
    rect(0, 0, _bounds, _bounds);
  popMatrix();
  
  pushMatrix();
    translate(-_bounds / 2, -_bounds / 2, -_bounds / 2);
    rect(0, 0, _bounds, _bounds);
  popMatrix();
  
  pushMatrix();
    translate(-_bounds / 2, -_bounds / 2, _bounds / 2);
    rect(0, 0, _bounds, _bounds);
  popMatrix();
}
​
void displayStats() {
  noStroke();
  textAlign(LEFT);
  textSize(16);
  
  fill(0);
  text("Total: " + _people.size(), 10, 20);
  text("Social dist: " + _socialDistanceCount + " (" + percentage(_socialDistanceCount, _people.size()) + "%)", 10, 40);
  
  fill(_normalColor);
  text("Healthy: " + _normalCount + " (" + percentage(_normalCount, _people.size()) + "%)", 10, 60);
  
  fill(_sickColor);
  text("Sick: " + _sickCount + " (" + percentage(_sickCount, _people.size()) + "%)", 10, 80);
  
  fill(_recoveryColor);
  text("Recovered: " + _recoveryCount + " (" + percentage(_recoveryCount, _people.size()) + "%)", 10, 100);
  
  fill(_deadColor);
  text("Passed: " + _deathCount + " (" + percentage(_deathCount, _people.size()) + "%)", 10, 120);
  
  fill(0);
  text("Days: " + _days, 10, 140);
}
​
void drawBar(int x, int y, int count, color barColor) {
  if (count > 0) {
    fill(barColor);
    rect(x, y, map(count, 0, _people.size(), 0, 200), 15);
  }
}
​
void displayGraph() {
  float x = 210;
  
  noStroke();
  noLights();
  
  drawBar(x, 17, population, color(0));
  drawBar(x, 36, _socialDistanceCount, color(0));
  drawBar(x, 55, _normalCount, _normalColor);
  drawBar(x, 72, _sickCount, _sickColor);
  drawBar(x, 93, _recoveryCount, _recoveryColor);
  drawBar(x, 112, _deathCount, _deadColor);
}
​
void displayEnd() {
  noStroke();
  fill(0);
  textAlign(CENTER);
  textSize(55);
  text("OUTBREAK DONE", width / 2, height / 2);
}
​
void percentage(value, maxValue) {
  return (value / maxValue * 100.0).toFixed(1);
}
​
void noDistTriggered() {
  socialDistance = 0;
  resetSim();
}
​
void lowDistTriggered() {
  socialDistance = 25;
  resetSim();
}
​
void highDistTriggered() {
  socialDistance = 85;
  resetSim();
}